最近暇つぶしにFalloutというゲームを買ってみたら、かなりハマってしまって
猛烈な勢いで時間を消費しています。短期間にゲームをやりこむと燃え尽きて
すぐ飽きてしまうのでほどほどにして現実でもクラフトしましょう。
今回はホームオートメーションの核となるBLEでRaspberryPiと通信してみます。
こちらにBLEの基礎について詳しい解説がありました。実際はライブラリに隠れているので
そこまで意識することはありませんがザっと読んでおくと大変勉強になります。
・BLEプログラムのプロトタイプを作る
ちょっと勉強して理解したつもりになったところでArduinoIDEのサンプルからBLEデバイスの
プロトタイプを作ってみました。
//==========================================================
// Include Header
//==========================================================
#include <BLEDevice.h>
#include <BLEServer.h>
#include <BLE2902.h>
//*****ヘッダ都度部******
//*********************
//==========================================================
// Macro Definition
//==========================================================
#define SERVER_NAME "ESP32_BLE_TEST" // サーバー名 各自設定する
//====シグナル定義====
//#define SIGNAL_ERROR 'E' // (異常発生:Error)
//#define SIGNAL_REQUEST 'r' // デバイス状態取得要求
//====UUID設定====
#define SERVICE_UUID "28b0883b-7ec3-4b46-8f64-8559ae036e4e" // サービスのUUID
#define CHARACTERISTIC_UUID_Notify "2049779d-88a9-403a-9c59-c7df79e1dd7c" // NotifyUUID
#define CHARACTERISTIC_UUID_RX "9348db8a-7c61-4c6e-b12d-643625993b84" // 受信用UUID
#define CHARACTERISTIC_UUID_TX "e303cfe5-b463-4b82-bbc3-e0789945b499" // 送信用UUID
//*****マクロ都度部******
//*********************
//==========================================================
// Function Prototype
//==========================================================
void BLE_Setup(void);
//****関数プロトタイプ都度部*****
//****************************
//==========================================================
// Global Variable
//==========================================================
BLECharacteristic *pCharacteristicTX; // 送信用キャラクタリスティック
BLECharacteristic *pCharacteristicRX; // 受信用キャラクタリスティック
BLECharacteristic *pCharacteristicDD; // データ送信要求キャラクタリスティック
BLEServer *pServer = NULL;
bool deviceConnected = false; // デバイスの接続状態
bool bInAlarm = false; // デバイス異常判定
bool oldDeviceConnected = false; //
//*****グローバル変数都度部******
//****************************
//----------------------------------------------------------
// 接続・切断時コールバック関数
//----------------------------------------------------------
class funcServerCallbacks: public BLEServerCallbacks {
void onConnect(BLEServer* pServer) {
deviceConnected = true;
}
void onDisconnect(BLEServer* pServer) {
deviceConnected = false;
}
};
//----------------------------------------------------------
// シグナル受信時のコールバック
//----------------------------------------------------------
class funcReceiveCallback: public BLECharacteristicCallbacks {
void onWrite(BLECharacteristic *pCharacteristicRX) {
// シリアルモニタに表示する
std::string rxValue = pCharacteristicRX->getValue();
if (rxValue.length() > 0) {
//受信したデータを全部表示
Serial.print("RECV_DATA: ");
for (int i = 0; i < rxValue.length(); i++) Serial.print(rxValue[i]);
Serial.println();
//*******************受信時処理の都度部**********************************
//*******************************************************
}
}
void onRead(BLECharacteristic *pCharacteristicRX) {
//*******************受信時処理の都度部**********************************
char send_str[] = "Hello world";
pCharacteristicRX->setValue(send_str);
Serial.println("BLE:Data Request");
//*******************************************************
}
};
//----------------------------------------------------------
// BLEセットアップ関数
//----------------------------------------------------------
void BLE_Setup(void) {
BLEDevice::init(SERVER_NAME); // 初期化処理を行ってBLEデバイスを初期化する
// Serverオブジェクトを作成してコールバックを設定する
pServer = BLEDevice::createServer();
pServer->setCallbacks(new funcServerCallbacks());
// Serviceオブジェクトを作成して準備処理を実行する
BLEService *pService = pServer->createService(SERVICE_UUID);
// Notify用のキャラクタリスティックを作成する
pCharacteristicTX = pService->createCharacteristic(
CHARACTERISTIC_UUID_TX,
BLECharacteristic::PROPERTY_NOTIFY
);
pCharacteristicTX->addDescriptor(new BLE2902());
// 受信用キャラクタリスティックを作成してシグナル受信時のコールバックを設定する
pCharacteristicRX = pService->createCharacteristic(
CHARACTERISTIC_UUID_RX,
BLECharacteristic::PROPERTY_WRITE
);
pCharacteristicRX->setCallbacks(new funcReceiveCallback());
// サービスを開始して、SERVICE_UUIDでアドバタイジングを開始する
pService->start();
BLEAdvertising *pAdvertising = pServer->getAdvertising();
pAdvertising->addServiceUUID(SERVICE_UUID);
pAdvertising->start();
}
//----------------------------------------------------------
// Set Up Function
//----------------------------------------------------------
void setup() {
Serial.begin(115200); //シリアル設定
BLE_Setup(); //BLEセットアップ
}
//----------------------------------------------------------
// Main Loop Function
//----------------------------------------------------------
void loop() {
// notifyしたいときはここに書く
if (deviceConnected) {}
//接続段時の処理
if (!deviceConnected && oldDeviceConnected) {
delay(500); // give the bluetooth stack the chance to get things ready
pServer->startAdvertising(); // restart advertising
//Serial.println("start advertising");
oldDeviceConnected = deviceConnected;
}
//接続開始時の処理
if (deviceConnected && !oldDeviceConnected) {
oldDeviceConnected = deviceConnected; // do stuff here on connecting
}
delay(100);
}
「都度部」と書かれたところに固有の処理を書くことで簡単にBLEデバイスを作れるように
しました。
具体的にはセントラルからデータが送信されると68行目のコールバック関数
が呼ばれ、データはrxValue[]に入っているのでこの値にその下の都度部に処理を書きます。
また、セントラルから読み出し指示があった時は84行目のonRead関数が呼ばれるので
pCharacteristicRX->setValue()にデータをセットすれば送信することができます。
本来は機能ごとにUUIDを振るのが正解っぽいですが送信データの先頭で処理を
場合分けすればいいかなと思ったのでUUIDは一つだけ使っています。
このプログラムでは単体テストできるようにセントラルから来たデータを
シリアルで書き出す処理、読み取り指示があった時は指定文字列を送信するコード
になっています。次にRaspberri Piから接続してデータをやり取りしてみます。
・Raspberry piから接続する
作ったデバイスにRaspberry Piから接続してみます。今回はテストなので
gattoolというソフトを使って直接値を見てみます。
まずはアドレスを調べます。
pi@raspberrypi:~ $ sudo hcitool lescan
LE Scan ...
3C:71:BF:F1:E6:7E (unknown)
3C:71:BF:F1:E6:7E ESP32_BLE_TEST
41:DD:FB:51:61:AB (unknown)
41:DD:FB:51:61:AB (unknown)
アドレスがわかったらCtrl＋Cで止めてしまいましょう。私の場合3C:71:BF:F1:E6:7E
であることがわかります。ESP32側のプログラムと一致しますね。
gatttool -b アドレス -I でデバイスを指定しconnectで接続します。
pi@raspberrypi:~ $ gatttool -b 3C:71:BF:F1:E6:7E -I
[3C:71:BF:F1:E6:7E][LE]> connect
Attempting to connect to 3C:71:BF:F1:E6:7E
Connection successful
characteristicsでキャラクタリスティックを見つけましょう。
[3C:71:BF:F1:E6:7E][LE]> characteristics
handle: 0x0002, char properties: 0x20, char value handle: 0x0003, uuid: 00002a05-0000-1000-8000-00805f9b34fb
handle: 0x0015, char properties: 0x02, char value handle: 0x0016, uuid: 00002a00-0000-1000-8000-00805f9b34fb
handle: 0x0017, char properties: 0x02, char value handle: 0x0018, uuid: 00002a01-0000-1000-8000-00805f9b34fb
handle: 0x0019, char properties: 0x02, char value handle: 0x001a, uuid: 00002aa6-0000-1000-8000-00805f9b34fb
handle: 0x0029, char properties: 0x10, char value handle: 0x002a, uuid: e303cfe5-b463-4b82-bbc3-e0789945b499
handle: 0x002c, char properties: 0x08, char value handle: 0x002d, uuid: 9348db8a-7c61-4c6e-b12d-643625993b84
今回はCHARACTERISTIC_UUID_RXにアクセスしたいのでハンドルは0x002dになります。
このハンドルを使って通信をしてみましょう。char-read-hnd ハンドル で読み取り、
char-write-cmdでデータを送信します。
[3C:71:BF:F1:E6:7E][LE]> char-read-hnd 0x002d
Characteristic value/descriptor: 48 65 6c 6c 6f 20 77 6f 72 6c 64
[3C:71:BF:F1:E6:7E][LE]> char-write-cmd 0x002d 30313233
ArduinoIEDのシリアルモニタを見るとなんかでています。Raspberry Pi側は
16進数になっているのでわかりずらいですが、アスキーコードに直すとちゃんと
データがやり取りできていることがわかります。
これで無事通信できていることがわかりました。まだBLEについて理解できていない
部分があるので使い方が間違っているかもしれませんが、データを送受信できるように
なったのでとりあえず動かせるようになります。今回作ったプロトタイププログラム
に色々追加してホームオートメーション用BLEネットワークを構築していきたいと
思います。
参考にさせて頂いたサイト
